po tekstam   po klyuchevym slovam   v glossarii   po saitam   perevod   po katalogu

5. Diagramma Gercshprunga-Ressela

Na kosmicheskom apparate Hipparcos provodilis' izmereniya bleska zvezd v dvuh polosah , v sobstvennoi fotometricheskoi sisteme Tycho. Imeyutsya formuly dlya perescheta etih velichin v standartnyi pokazatel' cveta B-V, no dlya udobstva eta velichina uzhe vnesena v katalog Vsego takaya fotometriya byla sdelana dlya 114 820 zvezd v Hipparcos, krome etogo dlya 2117 zvezd fotometricheskie dannye byli vzyaty iz nazemnyh istochnikov. Pole H39 (poziciya 259) neset informaciyu ob istochnike B-V (simvol G ili T - nazemnye nablyudeniya ili Tycho). Dlya 115 180 zvezd imeyutsya dannye i o spektral'nom klasse.

Individual'nye parallaksy pozvolyayut vychislit' absolyutnuyu zvezdnuyu velichinu ili svetimost' dlya kazhdoi zvezdy. Takim obrazom, imeetsya vse neobhodimoe dlya postroeniya diagrammy Gercshprunga-Ressela. Katalog Hipparcos daet unikal'nuyu vozmozhnost' postroit' diagrammu dlya lyuboi vyborki zvezd. Do poyavleniya etogo kataloga eto bylo nevozmozhno iz-za plohogo znaniya rasstoyanii. Diagrammy udavalos' stroit' tol'ko dlya teh zvezd, dlya kotoryh imelas' kosvennaya informaciya, chto oni nahodyatsya ot nas primerno na odinakovom rasstoyanii, naprimer, dlya zvezd odnogo zvezdnogo skopleniya.

Sleduet zametit', chto v programme Celestia voobshe ne predusmotrena rabota s diagrammoi Gercshprunga-Ressela.

Algoritm postroeniya diagrammy dostatochno prost i mozhet byt' legko dopolnen programmistom dlya resheniya bolee konkretnyh zadach, svyazannyh s ispol'zovaniem diagrammy Gercshprunga-Ressela.

V nachale programmy opredelyayutsya konstanty, opisyvayushie ohvat pryamougol'nika diagrammy, a takzhe otstup ramki diagrammy ot kraya graficheskogo okna i maksimal'nuyu otnositel'nuyu oshibku parallaksa. Dalee idet opisanie dvuh global'nyh peremennyh - masshtabnyh mnozhitelei, kotorye ispol'zuyutsya v procedure XY, a vychislyayutsya v glavnoi programme. Procedura XY perevodit i zvezdy v ekrannye koordinaty , .

Glavnaya programma nachinaetsya s sozdaniya graficheskogo okna i opredeleniya masshtabnyh mnozhitelei v sootvetstvii s razresheniem ekrana. Okno zalivaetsya belym cvetom, a cvet pera po umolchaniyu zadaetsya chernym. Zatem risuetsya obramlyayushii pryamougol'nik diagrammy i proishodit razmetka osei shtrihami v 3 pikselya i podpisyami s shagom 0.5 po i 5 po .

Listing 5.1. Postroenie diagrammy Gercshprunga-Ressela

Program HRBV; { Postroenie HR-diagrammy }
Uses HipMain,Graph,Math;
const
MagLow =15.0; MagHi =-5.0; { Diapazon po abs. zv. velichine }
BVLow =-0.5; BVHi = 2.0; { Diapazon po B-V }
Border = 50; { Otstup diagrammy ot kraya okna }
RelErr = 0.5; { Otnositel'naya tochnost' opredeleniya parallaksa}
var { gloabal'nye peremennye }
ScaleMg : double; { Masshtab po osi abs. zv. velichin }
ScaleBV : double; { Masshtab po osi pokazatelya cveta }
{ Procedura perescheta B-V i M v ekrannye koordinaty }
Procedure XY(B_V,Mag:single; var x,y : integer);
begin
x:=Border+Round((B_V-BVLow)*ScaleBV);
y:=Border++Round((Mag-MagHi)*ScaleMg);
end;
var
driver, mode : smallint; { Dlya inicializacii grafiki }
s : THipparcos; { Zvezda v Hipparcos }
r : double; { Rasstoyanie }
Mag : single; { Absolyutnayazvezdnayavelichina }
BV : single; { Pokazatel'cveta }
buf : string[15]; { Bufer dlya formirovaniya tekstovyh strok }
x,y,x1,y1 : integer; { Ekrannye koordinaty }
color : integer; { Cvet tochki }
begin
{ Inicializaciya graficheskogo okna }
driver:=detect; mode:=0; InitGraph(driver,mode,'D:/BP/BGI');
{ Opredelenie masshtabov po osyam }
ScaleMg:=(GetMaxY-2*Border)/(MagLow-MagHi);
ScaleBV:=(GetMaxY-2*Border)/(BVHi-BVLow);
{ Zalivka fona i ustanovka cveta }
SetFillStyle(SolidFill,White); Bar(0,0,GetMaxX,GetMaxY);
SetColor(Black);
{ Otrisovka obramlyayushei ramki }
XY(BVLow,MagHi,x,y); XY(BVHi,MagLow,x1,y1);
Rectangle(x,y,x1,y1);
{ Razmetka osi pokazatelya cveta }
SetTextJustify(CenterText,TopText);
BV:=BVLow;
repeat
XY(BV,15,x,y); Line(x,y,x,y+3);
Str(BV:0:1,buf); OutTextXY(x,y+5,buf);
BV:=BV+0.5;
until BV>BVHi;
{ Razmetka osi abs. zv. velichin }
SetTextJustify(RightText,CenterText);
Mag:=MagHi;
Repeat
XY(BVLow,Mag,x,y); Line(x,y,x-3,y);
Str(Mag:0:0,buf); OutTextXY(x-5,y,buf);
Mag:=Mag+5;
until Mag>MagLow;
OpenHipparcosMain;
InitCriteria('100.txt');
while ReadHipparcosMain(s) do
begin
if (s.info and NoPlx)<>0 then continue; { net parallaksa }
if (s.info and NoB_V)<>0 then continue; { net B-V }
if (s.info and NoVMag)<>0 then continue; { net V Mag }
if s.plx<=0.0 then continue; { "plohoi" parallaks }
if s.sigma.plx/s.plx>RelErr then continue; { nizkaya tochnost' }
ifnot inCelestia(s.HIP) then continue; { net v spiske }
r:=1000.0/s.plx; { Vychislenie rasstoyaniya v pk }
Mag:=S.VMag-5.0*log10(r)+5.0; {Vychisl. abs. zvezd. velichiny}
case s.SP[0] of { Opredelenie cveta tochki }
'O','B': color:=LightBlue;
'A' : color:=LightCyan;
'F','G': color:=Yellow;
'K','M': color:=LightRed;
else color:=LightGray;
end; { case }
XY(S.B_V,Mag,x,y); { Vychislenie ekrannyh koordinat tochki }
PutPixel(x,y,Color); { Postavit' tochku }
end; { while }
ClearCriteria;
CloseHipparcosMain;
end.

Sobstvenno cikl naneseniya zvezd na diagrammu yavlyaetsya ves'ma prostoi proceduroi. V nachale tela cikla proveryaetsya nalichie u zvezdy vseh neobhodimyh dlya diagrammy Gercshprunga-Ressela parametrov. Zatem proveryaetsya prisutstvie zvezdy v spiske, podgotovlennom programmoi Celestia. V nashem primere my zadali kriterii otbora zvezd c parallaksom bol'she 10 mas. Chislo takih zvezd sostavilo 22 982. Obrashaem vnimanie, chto pri ispol'zovanii 16-razryadnyh kompilyatorov spisok nomerov zvezd chislom bolee 16 383 ne pomestitsya v 64K segment, sleduet ispol'zovat' 32-razryadnyi kompilyator ili drugoi algoritm proverki nahozhdeniya zvezd v spiske. Konechno, takoi prostoi kriterii neslozhno zadat' i neposredstvenno v programme operatorom

Ris. 5.1. Diagramma Gercshprunga-Ressela dlya zvezd, nahodyashihsya na rasstoyanii blizhe 100 pk. Po osi absciss otlozhen pokazatel' cveta B-V, po osi ordinat - absolyutnaya zvezdnaya velichina.

Versiya dlya pechati